code:

@echo off
mode con:cols=55 lines=50
title PMS-VPN-ByPass
color 17

echo.
echo  Bypassing VPN by setting up a route through the 
echo  local gateway with a myPlex Class B network mask.
echo.
echo  By Dag Jonny Nedrelid - Thronic.com - 2015.3
echo.
echo.

echo. Finding local gateway ...
ipconfig | findstr /I /C:"Default Gateway" | findstr /I /C:".1" > %temp%\djgwinfo.txt
set /p djgwinfo=<"%temp%\djgwinfo.txt"
set djgwinfo=%djgwinfo:*: =%

echo. Finding current my.plexapp.com IP ...
ping -n 1 "my.plexapp.com"|findstr /I /C:"my.plexapp.com" > "%temp%\my.plexapp.com.txt"
set /p djplexinfo=<"%temp%\my.plexapp.com.txt"
set djplexinfo=%djplexinfo:*[=%
set djplexinfo=%djplexinfo:~0,-24%

:: Convert Plex IP to Class B.
for /f "tokens=1,2,3,4 delims=." %%a in ("%djplexinfo%") do set djplexinfo=%%a.%%b.0.0

:: Check if the route already exists.
route print -4 | findstr /I /C:"%djplexinfo%" > nul

if %errorlevel% equ 1 (
	echo. Adding new persistent route for %djplexinfo%.
	echo.
	echo. Traffic to myPlex is now routed to go through 
	echo. the local gateway %djgwinfo%, bypassing any VPN.
	echo.
	route -p add %djplexinfo% mask 255.255.0.0 %djgwinfo% > nul
) else (
	echo. Active route already found, not adding anything new.
	echo.
)

echo. Done. Press a key to exit.