code:

tell application "Aperture"
	activate
	set allProjects to every project
	repeat with i from 1 to count of allProjects
		set theProject to item i of allProjects
		set oldName to name of theProject
		if (my date_missing(oldName)) then
			set theImages to image versions of theProject
			if (count of theImages) is greater than 0 then
				set firstPicture to item 1 of theImages
				set theDate to value of EXIF tag "ImageDate" of firstPicture
				set newName to my date_format(theDate) & " " & oldName
				set name of theProject to newName
			end if
		end if
	end repeat
end tell

to date_missing(title)
	if (count of title) ≥ 10 then
		set potentialDate to text 1 thru 10 of title
		set tryDate to my find_date(potentialDate)
		if (tryDate is not "") then
			return false
		end if
	end if
	return true
end date_missing

to date_format(old_date)
	set {year:y, month:m, day:d} to old_date
	tell (y * 10000 + m * 100 + d) as string to text 1 thru 4 & "-" & text 5 thru 6 & "-" & text 7 thru 8
end date_format

on find_date(theString)
	set returnValue to ""
	set newDate to (current date)
	set savedDelimeters to AppleScript's text item delimiters
	set AppleScript's text item delimiters to {"-", ".", "/", ":"}
	if (count of text items of theString) is 3 then
		set {newDate's year, newDate's month, newDate's day} to (every text item of theString)
		set returnValue to newDate
	end if
	set AppleScript's text item delimiters to savedDelimeters
	return returnValue
end find_date