# Parse Erlang Crash Dumps and correlate mailbox size to the currently running
# function.
#
# Once in the procs section of the dump, all processes are displayed with
# =proc:<0.M.N> followed by a list of their attributes, which include the
# message queue length and the program counter (what code is currently
# executing).
BEGIN {
    threshold = 10000 # mailbox size
    procs = 0 # are we in the =procs entries?
    print "MESSAGE QUEUE LENGTH: CURRENT FUNCTION"
    print "======================================"
}

# Only bother with the =proc: entries. Anything else is useless.
procs == 0 && /^=proc/ { procs = 1 } # entering the =procs entries
procs == 1 && /^=/ && !/^=proc/ { exit 0 } # we're done


# Message queue length: 1210
# 1       2     3       4
/^Message queue length: / && $4 >= threshold { flag=1; ct=$4 }
/^Message queue length: / && $4 <  threshold { flag=0 }

# Program counter: 0x00007f5fb8cb2238 (io:wait_io_mon_reply/2 + 56)
# 1       2        3                  4                       5 6
flag == 1 && /^Program counter: / { print ct ":", substr($4,2) }

• A line is $0
  
• Every field of the line is $1, $2, $3, $4, ... $N, where the separator is defined by the variable FS -- the comments in the snippet above show this usage
  
• FS is the field-separator, as I said. It can be set per clause, globally, or whatever, depending on when you use the $N variables.
  
• OFS is the output field-separator, so that if you do OFS=":"; print $1, $2, you're separating all the values with a colon.
  
• NF tells you how many fields there are in a line
  
• NR is the current line number
  
• RS is the record separator and can be changed if you don't want newlines, similarly for ORS for the output
  

$ awk -f queue_fun.awk $PATH_TO_DUMP
MESSAGE QUEUE LENGTH: CURRENT FUNCTION
======================================
10641: io:wait_io_mon_reply/2
12646: io:wait_io_mon_reply/2
32991: io:wait_io_mon_reply/2
2183837: io:wait_io_mon_reply/2
730790: io:wait_io_mon_reply/2
...
10412: io:wait_io_mon_reply/2
2554519: some_server:handle_info/3
12443: io:wait_io_mon_reply/2
168785: io:wait_io_mon_reply/2
26314: io:wait_io_mon_reply/2

MononcQc fucked around with this message at 19:28 on Oct 23, 2013