code:

input over_bought = 80;
input over_sold = 20;
input KPeriod = 8;
input DPeriod = 5;
input priceH = high;
input priceL = low;
input priceC = close;
input slowing_period = 3;
input averageType = AverageType.SIMPLE;
input showBreakoutSignals = {default "No", "On FullK", "On FullD", "On FullK & FullD"};

input priceLookback = 8;
input FullDDipThreshold = 1;
input PriceDipThreshold = 0;

plot sfd = StochasticFull(over_bought, over_sold,  KPeriod,  DPeriod,  priceH,  priceL,  priceC,  slowing_period, averageType, showBreakoutSignals).FullD;
sfd.Hide();

def sfdMin = if (sfd[2] > sfd[1] and sfd[1] > sfd  and sfd[-1] > sfd) then sfd else Double.NaN;
def sfdMax = if (sfd[2] < sfd[1] and sfd[1] < sfd and sfd[-1] < sfd) then sfd else Double.NaN;

plot lowestInRange = Lowest(low, priceLookback);
lowestInRange.Hide();

def lowStartingRange = low[priceLookback];

plot priceDip = if (!IsNaN(sfdMin) and lowestInRange != lowStartingRange) then lowestInRange else Double.NaN;
plot sfdDip = if (!IsNaN(sfdMin) and lowestInRange !=
lowStartingRange) then sfdMin else Double.NaN;
priceDip.Hide();
sfdDip.Hide();

plot highestInRange = Highest(high, priceLookback);
highestInRange.Hide();

def highStartingRange = high[priceLookback];

plot pricePeak = if (!IsNaN(sfdMax) and highestInRange != highStartingRange) then highestInRange else Double.NaN;
plot sfdPeak = if (!IsNaN(sfdMax) and highestInRange != highStartingRange) then sfdMax else Double.NaN;
pricePeak.Hide();
sfdPeak.Hide();

def priorDipPrice = fold i = 1 to 100 with priorPriceDip = Double.NaN while IsNaN(priorPriceDip) do priceDip[i];
def priorDipStoch = fold j = 1 to 100 with priorStochDip =
Double.NaN while IsNaN(priorStochDip) do sfdDip[j];
def priorPeakPrice = fold k = 1 to 100 with priorPricePeak = Double.NaN while IsNaN(priorPricePeak) do pricePeak[k];
def priorPeakStoch = fold l = 1 to 100 with priorStochPeak = Double.NaN while IsNaN(priorStochPeak) do sfdPeak[l];

plot buyNow = if (priorDipPrice - priceDip > PriceDipThreshold and sfdDip - priorDipStoch > FullDDipThreshold) then low else Double.NaN;
buyNow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
buyNow.SetDefaultColor(Color.LIGHT_GREEN);
plot sellNow = if (pricePeak - priorPeakPrice > PriceDipThreshold and priorPeakStoch - sfdPeak > FullDDipThreshold) then high else Double.NaN;
sellnow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
sellnow.SetDefaultColor(Color.LIGHT_RED);