pre:

/*REXX program to generate a number triangle for partitions of a number.*/
numeric digits 400                    /*be able to handle large numbers.*/
parse arg N .;  if N=='' then N=25    /*No input?  Then use the default.*/
!.=0;   L=1;   mx=1;   parts=0;   aN=abs(N);   @.=0;   @.0=1
if N>0  then do     t=1  for 2
               do   r=1  for N;   aLine=
               parts=0
                 do c=1  for r;   _=gen#(r,c);      aLine=aLine right(_,L)
                 if r==n  then parts = parts + _    /*is this last line?*/
                 end   /*c*/           /* [↑]  sum #s only on last line.*/
               if t==2 then say center(strip(aLine,'L'),2+(N-1)*(L+1))
               end     /*r*/
             L=length(mx)
             end       /*t*/
say
if parts==0  then parts=partitions(aN)
say  'partitions('aN"):"  parts
exit                                   /*stick a fork in it, we're done.*/
/*──────────────────────────────────GEN# subroutine─────────────────────*/
gen#: procedure expose !. mx;            parse arg x,y;       $=1
if !.x.y\==0    then  return !.x.y     /*was this # generated before?   */
if 1<y & y<x-1  then  do q=2  to y;  if q<=x-y  then $=$+gen#(x-y,q);  end
mx=max(mx,$);   !.x.y=$                /*find max # length, remember #. */
return $                               /*return with the generated num. */
/*──────────────────────────────────PARTITIONS subroutine───────────────*/
partitions: procedure expose @.;       parse arg n
if @.n\==0  then return @.n            /*Already computed?    Return it.*/
$=0                                    /*[↓] Euler's recursive function.*/
            do k=1  for n;  _=n-(k*3-1)*k%2;         if _<0  then leave
            if @._==0  then x=partitions(_)
                       else x=@._
            _=_-k
            if _<0     then y=0
                       else if @._==0  then y=partitions(_)
                                       else y=@._
            if k//2  then $=$+x+y
                     else $=$-x-y
            end   /*k*/
@.n=$
return $