pre:

module Vector (vector, vec, veclen, inVector, toVector,
       	       pushback, checkrange, vecref, vecset)

// vectors
import Prelude


data vec = a: mkVector (arr = c (ray a)) (len = c int)

vector :: a: void -> vec a
vector = void: mkVector (cell (array 2)) (cell 0)

veclen :: a: vec a -> int
veclen = v: ref (len v)


inVector :: a: vec a -> iter a
inVector = v: inRayRange (ref (arr v)) 0 (ref (len v))

toVector :: a: iter a -> vec a
toVector = xs: {
    x = toRay xs;
    mkVector (cell x) (cell (length x))
}

pushback :: a: vec a -> a -> void
pushback = v:x: {
    n = veclen v;
    grow v (n + 1);
    set (ref (arr v)) n x;
    len v <- n + 1;
}

checkrange :: a: vec a -> int -> void
checkrange = v:k: {
    if (k < veclen v) {
        when (k < 0) void: {
	    error "checkrange: negative index";
	}
    } {
        error "checkrange: index too large";
    }
}

vecref :: a: vec a -> int -> a
vecref = v:k: {
    checkrange v k;
    (ref (arr v))_k;
}

vecset :: a: vec a -> int -> a -> void
vecset = v:k:x: {
    checkrange v k;
    set (ref (arr v)) k x 
}

grow :: a: vec a -> int -> void
grow = v:n: {
    k = length (ref (arr v));
    when (k < n) void: {
        k2 = max n (2 * k);
	arr2 = array k2;
	for (inZip (0...) (inRay (ref (arr v)))) ix: {
            set arr2 (fst ix) (snd ix);
	}
	arr v <- arr2
    }
}